Fonction ASP de recherche d’un utilisateur Active Directory

Nicolas — Sat, 24 Jul 2010 09:00:06 +0000

<%
Function RechercheUtilisateur(utilisateur, attribut)
 
'Déclaration des variables
Dim objConn, objRS
Dim Base, Filtre, Scope, Cmd
Dim ServeurAD, CompteAD, PwdAD, OU, DC, AttributFiltre
 
'Paramétrage
ServeurAD = "127.0.0.1"           'Machine hébergeant Active Directory
CompteAD = "DOMAINE\admin.ad"     'Utilisateur autorisé à interroger Active Directory
PwdAD = "********"                'Mot de passe de cet utilisateur
OU = "OU=Utilisateurs"            'OU à interroger
DC = "DC=domaine,DC=fr"           'DC à interroger
AttributFiltre = "sAMAccountName" 'Filtre de recherche de l'utilisateur
 
'Connexion à l'annuaire Active Directory
Set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Properties("User ID") = CompteAD
objConn.Properties("Password") = PwdAD
objConn.Properties("Encrypt Password") = true
objConn.Open
 
'Création de la requête
if attribut="" then
        'Permet la recherche simple de l'utilisateur (sans recherche d'attribut)
	attribut = "sAMAccountName"
end if
Base = " & ServeurAD & "/" & OU & "," & DC & ">"
Filtre = "(" & AttributFiltre & "=" & utilisateur & ")"
Scope = "subtree"
Cmd = Base & ";" & Filtre & ";" & attribut & ";" & Scope
set objRS = Server.CreateObject("ADODB.Recordset")
set objRS = objConn.Execute(Cmd)
 
If objRS.RecordCount = 0 Then
        'Aucun utilisateur trouvé
	RechercheUtilisateur = false
Else
	if IsNull(objRS(attribut)) then
		'Utilisateur trouvé, attribut recherché vide
		RechercheUtilisateur = "NULL"
	else
		if attribut="sAMAccountName" then
			'Utilisateur trouvé, pas d'attribut recherché
			RechercheUtilisateur = true
		else
			'Utilisateur trouvé, attribut recherché non-nul
			RechercheUtilisateur = objRS(attribut)
		end if
	end if
End If
 
'Fermeture du recordset et de la connexion
objRS.Close
objConn.Close
 
End Function
%>

Exemple de recherche avec un attribut en paramètre :

<%
Response.Write "E-mail : " & RechercheUtilisateur("utilisateur.alpha", "mail")
%>

Résultat :

E-mail : utilisateur.alpha@domaine.fr

Exemple de recherche « simple » :

<%
Response.Write "Utilisateur existant : "
if RechercheUtilisateur("utilisateur.alpha","")=true then
	Response.Write "oui"
else
	Response.Write "non"
end if
%>

Résultat :

Utilisateur existant : oui

Déterminer si une année est bissextile ou non

Nicolas — Tue, 19 Jan 2010 13:00:22 +0000

« Une année bissextile est une année divisible par 4. Une année est bissextile une fois sur 4. »

Ces deux affirmations sont bien ancrées dans la croyance populaire. Moi aussi, il y a peu, j’y croyais.

Pourtant… tout ceci est totalement faux. Le calendrier grégorien, en vigueur en France depuis 1532, indique qu’une année bissextile doit répondre à l’une de ces deux règles :

• Divisible par 400
• Divisible par 4 et non divisible par 100

Si vous faites le calcul, vous vous apercevrez que quasiment chaque année bissextile obéit à l’une de ces deux règles. Oui, quasiment : il y a effectivement des années divisibles par 4 qui n’obéissent à aucune de ces deux règles. Essayez avec 2100 par exemple : cette année est non divisible par 400, divisible par 4… mais divisible par 100. Il s’agit bel et bien d’une année non bissextile, alors que 2096 et 2104 seront des années bissextiles.

Évidemment, ça ne concerne que peu d’années : il y a en fait 97 années bissextiles en 4 siècles alors que la croyance populaire en compte 100. Mais dans certains domaines comme la généalogie, déterminer avec exactitude si une année est bissextile ou non peut avoir son importance.

Voici donc deux bouts de code en ASP et en PHP vous permettant de déterminer à coup sûr si une année est bissextile.

ASP :

function EstBissextile(annee)
    if annee mod 4 = 0 and annee mod 100 <> 0 or annee mod 400 = 0 then
        EstBissextile = true
    else
        EstBissextile = false
    end if
end function

PHP :

function EstBissextile($annee)
{
    if($annee%4 == 0 and $annee%100 != 0 or $annee%400 == 0)
        {
            $bissextile = true;
        }
    else
        {
            $bissextile = false;
        }
    return $bissextile;
}

Pour plus d’informations sur les années bissextiles, je vous recommande vivement la lecture de l’article Wikipédia à ce sujet.

blog.nicolas.pawlak.fr » ASP

Fonction ASP de recherche d’un utilisateur Active Directory

Déterminer si une année est bissextile ou non