Appuyez sur une touche pour continuer...

Il est possible de personnaliser ce message, tout en conservant sa fonction d’arrêt temporaire du déroulement du script, par ce moyen :

@echo off
echo Appuyez sur la touche de votre choix pour poursuivre...
pause>nul
exit

Cette personnalisation n’a pas qu’un but esthétique, elle peut-être nécessaire dans plusieurs cas :

Utilisation de PowerBatch

PowerBatch est un outil permettant entre autres de compiler des fichiers .bat pour les transformer en applications DOS/Windows. C’est un outil très intéressant, cependant le résultat de la commande pause s’affiche dans la langue de Shakespeare…

Ceci dit, il était peut-être préférable d’éviter le français à chaque message, si ça pouvait aider à éviter ce genre d’horreur orthographique :

Dans le cas où vous souhaiteriez créer un fichier .com à partir de votre fichier .bat, il semble donc préférable de contrôler réellement les messages d’information pouvant être affichés et les personnaliser si besoin.

Exécution sur un environnement en langue étrangère

Quoi, vous pensiez que sur un système en anglais, vous auriez un beau message de pause en français ? Il ne faut pas rêver… Cette méthode vous permet donc d’éviter l’aberration suivante :

Mon système est en anglais.
Mon script est en français.
 
Press any key to continue...

« Bah, il suffit juste de retirer 1 à la date du jour… »

Moui… mais non. Ce n’est pas en retirant 1 au 1^er janvier que ça nous donnera la date du 31 décembre.

Il existe sur Internet une multitude de solutions diverses, comme de gros scripts batch ou de simples scripts VBS. La solution que j’utilise n’est peut-être pas la meilleure, mais a le mérite d’être simple à mettre en place, simple à comprendre, et facilement adaptable.

Le principe est le suivant :

JOUR 0

- enregistrer la date du jour dans un fichier X (contiendra la date du jour 0)

JOUR 1

- récupérer le contenu du fichier X (contient la date du jour 0)
- remplacer le contenu du fichier X (contiendra la date du jour 1)

JOUR 2

- récupérer le contenu du fichier X (contient la date du jour 1)
- remplacer le contenu du fichier X (contiendra la date du jour 2)

Et ainsi de suite. Les fins de semaine, jours fériés et chômés ne sont pas une difficulté tant que le fichier X est écrasé après chaque journée d’utilisation et non pas de manière automatique. Ainsi, dans le cas d’un traitement du lundi au vendredi, le fichier X contiendra le lundi la date du vendredi.

Passons à la pratique.

Insertion de la date :

@echo off
echo %date% > %TEMP%\date_veille.txt
exit

A noter que vous pouvez adapter la date en fonction de vos envies :

- en retirant les slashs (echo %date:/=%),
- en remplaçant les slashs par des tirets (echo %date:/=-%),
- en changeant l’ordre pour année/mois/jour (echo %date:~6%/%date:~3,2%/%date:~0,2%)
- …

Récupération de la date :

@echo off
for /f "delims=" %%a in ('type %TEMP%\date_veille.txt') do set date_veille=%%a
echo La date de la veille est : %date_veille%
echo.
pause
exit

Il existe toutefois une alternative : placer la date du jour dans une variable… et mettre le script en pause, via un énorme sleep, jusqu’à l’utilisation du lendemain. Mais avoir un script lancé pendant peut-être plus de 10 heures n’est pas forcément une bonne idée…

Prenons comme exemple un script test.bat situé dans C:\Documents and Settings\nicolas\.

echo %~d0

Renvoie la lettre du lecteur (C:).

echo %~nx0

Renvoie le nom du fichier et son extension (test.bat).

echo %~x0

Renvoie l’extension du fichier (.bat).

echo %~f0

Renvoie le chemin complet au format long (C:\Documents and Settings\nicolas\test.bat).

echo %~sf0

Renvoie le chemin complet au format court (C:\DOCUME~1\nicolas\test.bat).

echo %~p0

Renvoie le chemin au format long sans le nom du fichier ni la lettre du lecteur (\Documents and Settings\nicolas\).

echo %~dp0

Renvoie le chemin au format long sans le nom du fichier (C:\Documents and Settings\nicolas\).

echo %~sp0

Renvoie le chemin au format court sans le nom du fichier ni la lettre du lecteur (\DOCUME~1\nicolas\).

Pour mettre en pratique, voici un script reprenant certaines de ces variables afin de tester le bon fonctionnement.

@echo off
echo Le fichier se nomme   : %~nx0
echo Son extension est     : %~x0
echo Il est lance depuis   : %~d0
echo Le chemin complet est : %~f0
echo.
pause
exit

Et voici le résultat :

Le fichier se nomme   : test.bat
Son extension est     : .bat
Il est lance depuis   : C:
Le chemin complet est : C:\Documents and Settings\nicolas\test.bat
 
Appuyez sur une touche pour continuer...

Il arrive parfois que l’on doive redémarrer Windows après une installation ou une configuration du système. Lorsque cette installation ou configuration se fait automatiquement dans le cadre d’un fichier .bat, le redémarrage provoque évidemment l’interruption du script… qui doit donc être relancé au redémarrage, et qui doit détecter où en est l’installation. Pour éviter ce genre de problèmes, bien souvent, les commandes sont découpées en plusieurs fichiers .bat qui doivent être exécutés l’un après l’autre.

Il est cependant possible de gérer le redémarrage du système avec relance automatique du script au redémarrage et reprise de l’installation ou de la configuration à la bonne étape.

Techniquement, il faut faire appel à la clé suivante de la base de registre :

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\RunOnce]

Et y insérer une nouvelle valeur chaîne avec ces paramètres :

Nom de la valeur : le nom de votre script, extension comprise (exemple : test.bat)
Données de la valeur : le chemin complet vers votre script (exemple : C:\scripts\test.bat)

La clé RunOnce est en fait une variante de la clé Run (qui contient des exécutables lancés à chaque démarrage), à la différence près que RunOnce est vidée après chaque exécution.

Pour reprendre l’exécution à la bonne étape, avant le redémarrage, le plus simple est peut-être de créer un fichier placé dans le dossier temporaire de l’utilisateur (désigné par la variable d’environnement %TEMP%). A chaque lancement, le script vérifie l’existence de ce fichier pour savoir quelle étape lancer. Une fois cette vérification faite, il faut que le script le supprime afin de ne pas se tromper d’étape à la prochaine exécution.

La principale difficulté est l’insertion dans la clé RunOnce. Récupérer le nom du fichier .bat, son chemin, et… « double antislasher » le chemin, c’est à dire remplacer :

C:\scripts\test.bat

par :

C:\\scripts\\test.bat

Pas si évident que cela… La solution :

@echo "%~nx0"="%CD:\=\\%\\%~nx0"

Autant dire qu’on ne tombe pas dessus par hasard. Voici un exemple complet, que vous pouvez utiliser, modifier… au gré de vos envies (et de vos besoins !) :

@echo off
 
REM --------------------------------------------------------------------
REM
REM Reexecuter un script .bat apres redemarrage
REM
REM --------------------------------------------------------------------
 
if exist %TEMP%\TESTBAT goto etape2
if not exist %TEMP%\TESTBAT goto etape1
 
:etape1
 
echo.
echo Reexecuter un script .bat apres redemarrage - Etape 1/2
echo --------------------------------------------------------------------
echo.
echo Veuillez indiquer quelques informations pour tester le script...
echo.
set /p id=identifiant bidon :
set /p mdp=Mot de passe bidon :
echo.
echo %id%>%TEMP%\TESTBAT
echo %mdp%>>%TEMP%\TESTBAT
 
echo Modification de la base de registre...
echo.
 
(
@echo Windows Registry Editor Version 5.00
@echo/
@echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\RunOnce]
@echo "%~nx0"="%CD:\=\\%\\%~nx0"
)>%TEMP%\TESTBAT.reg
 
regedit /s %TEMP%\TESTBAT.reg
del /q %TEMP%\TESTBAT.reg
 
cls
echo.
echo Reexecuter un script .bat apres redemarrage - Etape 1/2
echo --------------------------------------------------------------------
echo.
echo Les donnees ont ete enregistrees et seront affichees au redemarrage.
echo.
echo Testons a present le redemarrage du systeme
echo pour verifier que le script se relance bien.
echo.
 
set /p choix=Voulez-vous redemarrer immediatement (o/n) ?
if %choix%==o goto oui
if %choix%==n goto non
 
:oui
shutdown -r -t 0 & goto fin
 
:non
echo.
echo.
echo Votre systeme ne sera pas redemarre.
echo.
echo La suite au prochain demarrage de votre systeme.
echo.
pause
exit
 
:fin
exit
 
:etape2
 
echo.
echo Reexecuter un script .bat apres redemarrage - Etape 1/2
echo --------------------------------------------------------------------
echo.
 
for /f "delims=" %%a in ('type %TEMP%\TESTBAT') do (
if not defined id set id=%%a
)
for /f "delims=" %%a in ('type %TEMP%\TESTBAT') do set mdp=%%a
 
del /q %TEMP%\TESTBAT
 
echo Affichage des donnees precedemment demandees...
echo.
echo Le login bidon est : %id%
echo Le mot de passe bidon est : %mdp%
echo.
echo Le test est termine. Si vous redemarrez, rien ne se lancera...
echo.
pause
exit

Il est possible de la rajouter via un exécutable que l’on peut trouver sur Internet (comme wget !), mais comment faire lorsqu’il n’est pas possible d’y rajouter quoi que ce soit (en raison d’une politique de sécurité, notamment) ou que l’on veut une solution « universelle » ?

Et bien… avec un ping. Un simple ping qui, correctement paramétré, ne rendra la main qu’à l’issue d’un temps déterminé.

ping 127.0.0.1 -w 1000 -n 15 > nul

Explications :

- Le paramètre w détermine le temps d’exécution de chaque requête ICMP (en millisecondes).
- Le paramètre n détermine le nombre de requêtes ICMP à tenter.
- Le renvoi vers nul permet d’éviter tout affichage du résultat, puisqu’il ne nous intéresse pas.

De cette façon, dans l’exemple, nous avons 15 requêtes de 1000 millisecondes effectuées avant de « rendre la main », de façon totalement transparente pour l’utilisateur.

Toutefois, pour une durée souhaitée n, le temps d’exécution sera de (n-1) secondes. Il convient donc d’incrémenter de 1 la durée souhaitée.